On project compile, the created cam data is converted internally into a global variable list.
Each cam is represented by the data structure MC_CAM_REF. You can access this data structure by means of the IEC program or by preprocessing functions and function blocks. It is available by the SM3_Basic library.
A function block that describes a cam can also be generated or populated by the IEC program at runtime.
Example
Definition of the data structure:
TYPE mySMC_CAMTable_LREAL_10000_2 :
STRUCT
Table: ARRAY[0..9999] OF ARRAY[0..1] OF LREAL;
(* set all scaling definitions to 0 and 1
result: all values of the table are not scaled *)
fEditorMasterMin: REAL := 0;
fEditorMasterMax: REAL := 1;
fEditorSlaveMin: REAL := 0;
fEditorSlaveMax: REAL := 1;
fTableMasterMin: REAL := 0;
fTableMasterMax: REAL := 1;
fTableSlaveMin: REAL := 0;
fTableSlaveMax: REAL := 1;
END_STRUCT
END_TYPE
Instantiating the data structure:
Cam: MC_CAM_REF;
Cam_PointArray : mySMC_CAMTable_LREAL_10000_2;
Calculating the cam:
Cam.byType:=2;
Cam.byVarType:=6;
Cam.nTappets:=0;
Cam.strCAMName:='myCAM';
Cam.pce:= ADR(CAM_PointArray);
FOR i:=0 TO 9999 DO
(* example cam: master 0..360, slave 0..100,
constant velocity *)
Cam_PointArray.Table[i][0]:=UDINT_TO_LREAL(I)/10000 * 360; (* X *)
Cam_PointArray.Table[i][1]:=UDINT_TO_LREAL(I)/10000 * 100; (* Y *)
END_FOR
Cam.nElements:=10000
Cam.xStart:=0.0;
Cam.xEnd:=360.0;
In order to allow for easy access to the function blocks, they are collected and listed in the g_CAMManager global variable with the Count property and the GetCAM(int n) method.
Example
Access to data objects of the MC_CAM_REF function block:
PROGRAM CAMManageRef
VAR
pCAM_Ref: POINTER TO MC_CAM_REF;
n: INT;
i: INT;
END_VAR
n := g_CAMManager.Count;
FOR i:=0 TO n-1 DO
pCAM_Ref := g_CAMManager.GetCAM(i); (* Processing pCAM_Ref*)
END_FOR
See also
A cam can be created in an IEC program without using the cam editor.
Example
Declaration:
VAR
i: INT;
CAM: MC_CAM_REF := (
byType:=2, (* not-equidistant *)
byVarType:=2, (* UINT *)
nElements:=128,
xStart:=0,
xEnd:=360);
Table: SMC_CAMTable_UINT_128_2 := (
fEditorMasterMin := 0, fEditorMasterMax := 360,
fTableMasterMin := 0, fTableMasterMax := 6000,
fEditorSlaveMin := 0, fEditorSlaveMax := 360,
fTableSlaveMin := 0, fTableSlaveMax := 6000);
END_VAR
Implementation:
(* Generate cam (example: line); unique *)
FOR i:=0 TO 127 DO
Table.Table[i][0] := Table.Table[i][1] := REAL_TO_UINT(i / 127.0 * 6000);
END_FOR
(* Link pointer; must be done in every cycle *)
CAM.pce := ADR(Table);
This generated cam can be specified in the MC_CamTableSelect function block and its output used again for MC_CamIn.
