变量类型的属性关键字

通用常量是功能块 VAR_GENERIC CONSTANT 声明区中的变量，在分配功能块实例之前，该变量不会被分配初始化值。

语法：功能块说明：

FUNCTION_BLOCK <function block name>
VAR_GENERIC CONSTANT
    <generic constant name> : <integer data type> := <initial value>; //Initial value will be overwritten
END_VAR
;

例如，您可以在功能块中使用通用常量（整数数据类型）来表示数组大小或字符串长度。仅在编译检查时需要初始值 <initial value>。在运行时，值被覆盖。

语法：功能块实例说明：

PROGRAM PLC_PRG
VAR
    <fb instance name> : <function block name> < <literal> >;
    <fb instance name> : <function block name> <( <expression> )>;
END_VAR
;

在声明功能块实例时，将为常量分配一个仅对此实例有效的特定值。为此，值 <literal> 在尖括号中，添加到功能块 <function block name> 作为数据类型。

作为替代方法，可添加表达式 <expression>。将它括在括号中，以便在表达式中使用 < 或 > 等符号，并帮助您保持代码的唯一性。

示例：具有可参数化数组变量的通用功能块：

下列代码示例演示了如何定义可以处理任意长度数组的功能块。功能块具有通用但长度恒定的数组。此上下文中，术语“常量”意味着，尽管每个功能块实例的数组长度不同，但在对象的生存期内保持不变。

这在库编程中是有用的，例如，用于实现通用库 POU。

FUNCTION_BLOCK FB_MyString 
VAR_GENERIC CONSTANT
    maxlen : UDINT := 1;
END_VAR
VAR
    test : ARRAY[0..maxlen-1] OF BYTE;
END_VAR
;

PROGRAM PLC_PRG
VAR CONSTANT
    cconst: DINT := 1000;
END_VAR
VAR    
    fbMyString1 : FB_MyString<100>;
    fbMyString2 : FB_MyString<(2 * cconst)>;
    arrMyString : ARRAY [0..5] OF FB_MyString<100>;
END_VAR
;

继承

具有一般常量的功能块还可以使用继承构造 EXTENDS 和 IMPLEMENTS。

继承示例：

INTERFACE IString 
METHOD Append : BOOL 
VAR_INPUT     
    strAppend : IString; 
END_VAR 
METHOD Assign : BOOL
VAR_INPUT     
    stringIn: String; 
END_VAR 
METHOD ToString : STRING
VAR_INPUT 
END_VAR 
PROPERTY Length : DINT

FUNCTION_BLOCK MyString 
VAR_GENERIC CONSTANT        
    maxlen : UDINT; 
END_VAR 
IMPLEMENTS IString

FUNCTION_BLOCK LongString EXTENDS MyString<1000>

FUNCTION_BLOCK MySpecialString 
VAR_GENERIC CONSTANT        
    maxlen2 : UDINT:= 1; 
END_VAR 
EXTENDS MyString<maxlen2>
METHOD ToLatin1: STRING

PROGRAM PLC_PRG 
VAR CONSTANT     
    cconst: DINT := 1000; 
END_VAR
VAR     
    string1 : MyString<100>;
    string2 : MyString<(2 * cconst)>;
    derived1 : LongString;
    derived2 : MySpecialString<100>;
END_VAR 
string1.Assign ('Welt'); 
string2.Assign ('Hallo '); 
string2.Append(string1); 
derived2.ToLatin1('Hello World');